reset
set terminal x11 enhanced font "terminal-14"
set term pngcairo font "Arial,12"
set output "/tmp/plot.png"

# This first part up to 'set yrange [0:2]' is just to generate some data
set sample 500
set table 'stats1.dat'
plot [0:10] 0.5+invnorm(rand(0))*2
unset table

unset key

set style fill transparent solid 0.5 noborder

set yrange [-3:5]
set style fill transparent solid 0.5 noborder
set style textbox opaque noborder fillcolor rgb "#30FFFFFF"

stats 'stats1.dat' u 1:2
show variables all
set arrow 1 from STATS_pos_min_y, graph 0.1 to STATS_pos_min_y, STATS_min_y fill
set arrow 2 from STATS_pos_max_y, graph 0.9 to STATS_pos_max_y, STATS_max_y fill
set label 1 at STATS_pos_min_y, graph 0.1 sprintf("min %f",STATS_min_y) center offset 0,-1 front boxed
set label 2 at STATS_pos_max_y, graph 0.9 sprintf("max %f",STATS_max_y) center offset 2,1 front boxed
set arrow 3 from graph 0, first STATS_median_y to graph 1, first STATS_median_y nohead front
set label 3 at graph 1, first STATS_median_y sprintf("median %f",STATS_median_y) right offset 0,0.4 front boxed
set arrow 4 from graph 0, first STATS_mean_y to graph 1, first STATS_mean_y nohead dt "." lw 2 front
set label 4 at graph 0, first STATS_mean_y sprintf("mean %f",STATS_mean_y) left offset 0.8,0.4 front boxed
#set label 5 at graph 0, first STATS_mean_y+STATS_stddev_y sprintf("{/Symbol s} %.2f",STATS_stddev_y) left offset 0.8,0.4 front boxed
plot STATS_min_y with filledcurves y1=STATS_mean_y lt 1 lc rgb "#bbbbdd", \
STATS_max_y with filledcurves y1=STATS_mean_y lt 1 lc rgb "#bbddbb", \
STATS_mean_y+STATS_stddev_y with filledcurves y1=STATS_mean_y-STATS_stddev_y lt 1 lc rgb "#ddbbbb", \
'stats1.dat' u 1:2 w p pt 6 lc rgb "#ff0000"